+ Rispondi al messaggio
Pagina 1 di 2 12 ultimoultimo
Visualizzazione dei risultati da 1 a 10 su 17

Ricerca ed estrazione di stringa

  1. #1
    iemmgi non  in linea Novello
    Ciao,

    ho un file xls ed in colonna A c' una stringa di dati.
    All'interno di questa stringa di dati ci potrebbero essere i dati che mi interessa portare sulla colonna B.
    I dati da portare (sottostringa della colonna A) devono essere individuati facendo riferimento ad un altro file dove sono contenute tutte le sottostringhe valide !!

    Help !

    Grazie
    G

  2. #2
    GiuseppeMN non  in linea Scribacchino
    Buona sera, iemmgi;
    non mi ben chiaro il processo che vuoi svolgere.
    Quello che non ho capito :
    se nella colonna "A" del File#1 hai un Record del tipo "Mario Rossi" e nel File#2 hai come sottostringa "Rossi", vuoi portare nella colonna "B" del File#1 solo "Rossi" o "Mario Rossi"

    Grazie delle precisazioni che vorrai fornirmi.

    A disposizione.

    Giuseppe.

  3. #3
    iemmgi non  in linea Novello
    Ciao,

    quello che voglio portare solo "Rossi".

    Es:
    File 1 colonna A
    Mario Bianchi
    Mario Rossi
    Mario Verdi

    File 2 Colonna A
    Bianchi
    Verdi

    Il risultato della colonna B sul file 1 dovr essere:
    Bianchi
    Null (non tra le scelte valide)
    Verdi




    Grazie
    G

  4. #4
    Canapone non  in linea Scolaretto
    Ciao a tutti,

    potresti provare con un INDICE matrice.

    Nella formula d'esempio, nel foglio2 in A1:A100 i cognomi.

    In B2 del foglio1 per estrarre l'eventuale stringa:

    =INDICE(Foglio2!$A$2:$A$100;CONFRONTA(1;RICERCA("*"&Foglio2!$A$2:$A$100&"*";A2);0))
    
    Se usi Excel 2007 o versioni successive:

    =se.errore(INDICE(Foglio2!$A$2:$A$100;CONFRONTA(1;RICERCA("*"&Foglio2!$A$2:$A$100&"*";A2);0));"")
    
    Le formula devono essere confermate con control+maiusc+invio: sono formule matriciali.

    Qui trovi qualche informazione sul loro uso e funzionamento

    Utilizzo della formula matrice con Excel Luca Franchi – Blog


    Saluti
    Ultima modifica di Canapone; 03-01-2013 14:05 

  5. #5
    Canapone non  in linea Scolaretto
    Cos non hai bisogno del control+maiusc+invio

    Excel 2007-2010

    =SE.ERRORE(INDICE(Foglio2!$A$2:$A$10;CONFRONTA(1;INDICE(RICERCA("*"&" "&Foglio2!$A$2:$A$10&" "&"*";" "&$A2&" "););0));"")
    
    Versioni precedenti

    =se(val.errore(INDICE(Foglio2!$A$2:$A$10;CONFRONTA(1;INDICE(RICERCA("*"&" "&Foglio2!$A$2:$A$10&" "&"*";" "&$A2&" "););0)));"";INDICE(Foglio2!$A$2:$A$10;CONFRONTA(1;INDICE(RICERCA("*"&" "&Foglio2!$A$2:$A$10&" "&"*";" "&$A2&" "););0)))
    

    Nelle formule, se servisse, ho fatto in modo che estraggano "Bianchi" solo se trovano "Bianchi" e non -esempio- "Bianchini".

    Spero sia d'aiuto

  6. #6
    iemmgi non  in linea Novello
    Ciao,

    grazie e proprio quello che mi serve.
    Uso excel 2010 - ma ho notato che se la stringa non proprio quella non funziona.
    Nel senso se cerco 123456 e nel file dove cercare c' 1234567 non trova la stringa.

    Mi puoi aiutare ?

    Grazie
    g

  7. #7
    Canapone non  in linea Scolaretto
    Ciao,

    cos estrae 123456 in stringhe del tipo 01234567000; la riconosce ed isola solo la sottostringa fra quelle indicate in a2:a10

    =SE.ERRORE(INDICE(Foglio2!$A$2:$A$10;CONFRONTA(1;INDICE(RICERCA("*"&Foglio2!$A$2:$A$10&"*";$A2););0));"")
    
    Ho levato gli spazi vuoti dalla formula.

    Edit: per intendersi se vuoi estrarre non sono "rossi" ma anche "rossini" o "grossi", basta scrivere le sottostringhe nell'elenco in A2:A10 ed aggiustare la formula di ricerca estendendone l'area di riferimento (A$2:A$500).

    Saluti
    Ultima modifica di Canapone; 03-01-2013 17:05 

  8. #8
    iemmgi non  in linea Novello
    Fantastico - GRAZIE !!!!!!!

  9. #9
    terrasamba non  in linea Novello
    Quote Originariamente inviato da Canapone Visualizza il messaggio
    Ciao,

    cos estrae 123456 in stringhe del tipo 01234567000; la riconosce ed isola solo la sottostringa fra quelle indicate in a2:a10

    =SE.ERRORE(INDICE(Foglio2!$A$2:$A$10;CONFRONTA(1;INDICE(RICERCA("*"&Foglio2!$A$2:$A$10&"*";$A2););0));"")
    

    Ho levato gli spazi vuoti dalla formula.

    Edit: per intendersi se vuoi estrarre non sono "rossi" ma anche "rossini" o "grossi", basta scrivere le sottostringhe nell'elenco in A2:A10 ed aggiustare la formula di ricerca estendendone l'area di riferimento (A$2:A$500).

    Saluti
    Ciao, senza aprire una nuova discussione, io avrei questo problema:
    ho una colonna E con del testo da E5 a E100 e vorrei estrarle singolarmente confrontandole con altre colonne.

    Esempio:
    Nello stesso foglio:
    Colonna Strighe "E"(Range E5:E100);
    Colonna Valori per confronto "BC" (Range BC1:BC16);

    Come dovrei modificare la formula indicata sopra? Ho provato ma non ci riesco... Grazie!

  10. #10
    Canapone non  in linea Scolaretto
    Ciao,

    in E5 la stringa da dove vuoi estrarre - se esiste- una delle stringhe in BC1:BC16

    In F5:

    =SE.ERRORE(INDICE(BC$1:BC$16;CONFRONTA(1;INDICE(RICERCA("*"&BC$1:BC$16&"*";E5););0));"")
    
    Spero sia d'aiuto

+ Rispondi al messaggio
Pagina 1 di 2 12 ultimoultimo

Potrebbero interessarti anche ...

  1. Estrazione caratteri da una stringa
    Da ljt nel forum Visual Basic .Net
    Risposte: 31
    Ultimo Post: 02-12-2019, 12:57
  2. estrazione di caratteri da parte di una stringa
    Da Newton nel forum Visual Basic 6
    Risposte: 3
    Ultimo Post: 11-03-2011, 23:41
  3. estrazione di una stringa da un nomefile
    Da Newton nel forum Visual Basic 6
    Risposte: 7
    Ultimo Post: 25-11-2009, 15:42
  4. [Access] estrazione dati da stringa
    Da brian nel forum Microsoft Access
    Risposte: 11
    Ultimo Post: 09-12-2008, 00:15
  5. problemi con estrazione stringa
    Da dani83 nel forum Microsoft Word
    Risposte: 7
    Ultimo Post: 09-08-2007, 12:12