Problemi creazione campo di una tabella Precisione Doppia

Ciao a tutti,
ho provato a cercare in rete una soluzione al mio problema, ma per miei limiti, non sono giunto a capo del mio problema.
Ho la necessità di aggiungere un campo in una tabella che creo in questo modo:

  strSQL = "SELECT SupportoDettaglio.[Acr Contr], SupportoDettaglio.[Descrizione Contratto], SupportoDettaglio.Elemento, SupportoDettaglio.[Codice Titolo], SupportoDettaglio.ISIN, SupportoDettaglio.[Des VM], SupportoDettaglio.Valore, SupportoDettaglio.[Descrizione Ente Emittente], SupportoDettaglio.[Patrimonio Dossier], SupportoDettaglio.[% su Patr Dossier], Null as [Ricalcola %], Null AS Sforamento, First(SupportoDatasim.[Perce min]) AS [Perce min], First(SupportoDatasim.[Perce MAX]) AS [Perce MAX], First(SupportoDatasim.[Linea Gestione]) AS [Linea Gestione], Null AS Tipologia INTO NEWSupportoDettaglio"
  strSQL = strSQL + " FROM SupportoDettaglio INNER JOIN SupportoDatasim ON (SupportoDettaglio.[Acr Contr] = SupportoDatasim.[Acr contratto]) AND (SupportoDettaglio.Elemento = SupportoDatasim.[Raggr Titoli])"
  strSQL = strSQL + " GROUP BY SupportoDettaglio.[Acr Contr], SupportoDettaglio.[Descrizione Contratto], SupportoDettaglio.Elemento, SupportoDettaglio.[Codice Titolo], SupportoDettaglio.ISIN, SupportoDettaglio.[Des VM], SupportoDettaglio.Valore, SupportoDettaglio.[Descrizione Ente Emittente], SupportoDettaglio.[Patrimonio Dossier], SupportoDettaglio.[% su Patr Dossier], Null, Null"

visto che così facendo i campi che mi crea sono Binari, (vedi sotto i campi)

Null as [Ricalcola %],
Null AS Sforamento,
Null AS Tipologia

ho pensato di bypassare il problema in questo modo:

  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Tipologia") = False Then DBEngine(0)(0).Execute "ALTER TABLE NEWSupportoDettaglio ADD COLUMN Tipologia TEXT(3)"
  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Sforamento") = False Then DBEngine(0)(0).Execute "ALTER TABLE NEWSupportoDettaglio ADD COLUMN Sforamento TEXT(25)"
  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Ricalcola%") = False Then DBEngine(0)(0).Execute "ALTER TABLE NEWSupportoDettaglio ADD COLUMN Ricalcola% DOUBLE"

unico problema nella parte in rosso che mi restituisce il seguente errore "ERRORE DI SINTASSI NELLA DEFINIZIONE DEL CAMPO."
non riesco assolutamente a capire come correggerlo.

Grazie a tutti per eventuali dritte.

Ciaoooooo

Hai provato a mettere

cDbl(0) As ....

Ovviamente viene valorizzato a Zero... ma siccome un DOUBLE non supporta Null il tuo metodo non va bene.

Io non uso MAI quei metodi per modificare campi in Tabelle, sono nella sostanza incontrollabili..., se hai come BE JET, meglio di usare il codice....

https://docs.microsoft.com/en-us/off...eld-method-dao

P.S. Attenzione ai caratteri SPECIALI... e [%] è molto molto pericoloso usato come hai fatto tu...!

Se vuoi usare un comando DDL

DBEngine(0)(0).Execute "ALTER TABLE NEWSupportoDettaglio ADD COLUMN Ricalcola Double(Fixed,3)"

Ma non l'ho provato... e non sono certissimo che DAO supporti i comandi DDL...

Grazie Alex preziosissimo come al solito.

Ho risolto in questo modo:
nella prima creazione della tabella ometto i 3 campi che mi danno problemi.


Successivamente ho sostituito i comandi SQL con il seguente codice:

Dim fld As DAO.Field
  
  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Tipologia") = False Then
    Set fld = CurrentDb.TableDefs("NEWSupportoDettaglio").CreateField("Tipologia", dbText, 3)
    CurrentDb.TableDefs("NEWSupportoDettaglio").Fields.Append fld
  Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
  End If
  
  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Sforamento") = False Then
    Set fld = CurrentDb.TableDefs("NEWSupportoDettaglio").CreateField("Sforamento", dbText, 25)
    CurrentDb.TableDefs("NEWSupportoDettaglio").Fields.Append fld
  Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
  End If
  
  If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Ricalcola") = False Then
    Set fld = CurrentDb.TableDefs("NEWSupportoDettaglio").CreateField("Ricalcola", dbDouble)
    CurrentDb.TableDefs("NEWSupportoDettaglio").Fields.Append fld
  Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
  End If
  Set fld = Nothing

Prendi in considerazione anche questa opzione nativa che sfrutta CreateField, la sostanza è la medesima ma risulta più pulito:

Dim tdf As DAO.Tabledef

Set tdf= CurrentDb.TableDefs("NEWSupportoDettaglio")
If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Tipologia") = False Then
    tdf.Fields.Append tdf.CreateField("Tipologia", dbText,3) 
Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
End If

If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Sforamento") = False Then
    tdf.Fields.Append tdf.CreateField("Sforamento", dbText,25) 
Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
End If
  
If campoEsiste(CurrentDb, "NEWSupportoDettaglio", "Ricalcola") = False Then
    tdf.Fields.Append tdf.CreateField("Ricalcola", dbDouble) 
Else: MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
End If

Set tdf=Nothing

Personalmente però avrei scritto la funzione in questo modo, mi pare decisamente più tecnica e leggibile:

Function AddField()
    On Error GoTo Err_Handler
    Dim tdf As DAO.TableDef
    
    Set tdf = DBEngine(0)(0).TableDefs("NEWSupportoDettaglio")
    tdf.Fields.Append tdf.CreateField("Tipologia", dbText, 3)
    tdf.Fields.Append tdf.CreateField("Sforamento", dbText, 25)
    tdf.Fields.Append tdf.CreateField("Ricalcola", dbDouble)

Exit_Here:
    Set tdf=Nothing
    Exit Function

Err_Handler:
    Select Case Err.Number
        Case 3191:
            MsgBox ("Il campo che si vuole aggiungere esiste già nella tabella, per tanto non verrà effettuata nessuna operazione")
            Resume Next
        Case Else
            MsgBox Err.Number & vbNewLine & Err.Description
            Resume Exit_Here
    End Select
End Function

Grazie Alex