Errore di sintassi in funzione DLookup con date

Buonasera a tutti.

Ho creato un funzione pubblica che ha lo scopo di ritornare il valore del prezzo del prodotto in vigore al momento dell'allestimento della fattura.

La funzione cerca nella tabPrezzi il prezzo controllando l'IDProdotto, l'IDListino e confrontando la data della fattura con le date di inizio e fine validità del prezzo.

Questo il codice:

Public Function retrieveIdPrezzoUnitario(ByVal nIDProdotto As Long, ByVal nIDListino As Long, ByVal dDataMovimento As Date) As Variant

'Converto data nel sistema anglosassone
Dim ConvertedData As Date
ConvertedData = Format$(dDataMovimento, "mm/dd/yyyy")

' Imposta valore di default = 0
retrieveIdPrezzoUnitario = 0

' Ricerca il Prezzo
Dim varRtm As Variant
varRtm = DLookup("[PrezzoUnitario]", "tabPrezzi", "[IDProdotto] =" & nIDProdotto & " AND [IDListino]=" & nIDListino & " AND [DataFineValidita]>#" & ConvertedData & "# AND [DataInizioValidita]<#" & ConvertedData & "#")

' Ritorna il valore
 If Not IsNull(varRtm) Then retrieveIdPrezzoUnitario = varRtm
 End Function

Ottengo però un errore di sintassi nella query dei criteri della funzione Dlookup (errore run-time 3075).
Non riesco a capire dove si trovi, mi sembra tutto corretto.

Grazie per l'aiuto!

Leggi questo
https://masterdrive.it/microsoft-acc...pi-data-56461/

Grazie Alex.
Nel frattempo mi sono già letto il tuo articolo (mi ricordavo di averlo letto).
Ora ho risolto così:

Public Function retrieveIdPrezzoUnitario(ByVal nIDProdotto As Long, ByVal nIDListino As Long, ByVal dDataMovimento As Date) As Variant

' Imposta valore di default = 0
retrieveIdPrezzoUnitario = 0

' Ricerca il Prezzo
Dim varRtm As Variant
varRtm = DLookup("[PrezzoUnitario]", "tabPrezzi", "[IDProdotto] = " & nIDProdotto & " AND [IDListino] = " & nIDListino & " AND [DataFineValidita]>" & CLng(dDataMovimento) & " AND [DataInizioValidita]<" & CLng(dDataMovimento))

' Ritorna il valore
 If Not IsNull(varRtm) Then retrieveIdPrezzoUnitario = varRtm
 End Function

Se ho capito bene, questo è il modo in cui consigli di procedere quando si tratta di passare query (con date) a JET?

Dipende... se usi i Parameters non serve... se usi ad esempio DlookUp o la proprietà Filter o costruisci il predicato SQL... questo è per me il metodo più pulito, ma equivale agli altri.

Grazie mille, molto interessante.